<!--#include file="config/unique.asp"-->
<!--#include file="libraries.asp"-->
<%

On Error Resume Next
Set Jpeg = Server.CreateObject("Persits.Jpeg")
If err.number = 0 then
	If CDate(Jpeg.Expires) > Now then
		JpegVer = Mid(Jpeg.Version, 3, 1)
		JpegVer = CLng(JpegVer)
		If JpegVer > 3 then isASPJpeg = True
	End If
End If
On Error Goto 0

gennumber = CryptText(Request.Cookies("gennumber" & strSUnique), key, True)

If isASPJpeg then
	With Jpeg
		.Open Server.MapPath("img\tn.jpg")
		.Quality = 100
		.Canvas.Font.Bold = True
		.Canvas.Font.Underlined = False
		.Canvas.Font.Italic = False
		.Canvas.Font.Color = &h3F3F3F
		.Canvas.Font.Quality = 1
		.Canvas.Font.Size = 22
		.Canvas.Font.Family = "Georgia"
		TitleWidth = .Canvas.GetTextExtent(gennumber)
		.Canvas.Print (.Width - TitleWidth) / 2, .Height - 22, gennumber
		.SendBinary
	End With
	Set Jpeg = Nothing
Else
	gennumber = CStr(gennumber)
	pos = Request("pos")
	pic = Mid(gennumber, pos, 1)

	Response.Redirect "img/tn" & pic & ".jpg"
End If
%>